// RULES file

ONSETS
// This is currently unused.
{ { [-son] ([+nas]),  // k(n), kh, g(n), gh(n), c(h), ^j(~n), ^jm, ^jh,
                      // .t(h), .d(h), t(m), th, d, dh(m), p(h), b(h),
                      // ^s, ^sn, ^sm, .s(.n), s, sn, sm, h, hn, hm
    [-son +cont +Coronal] [-cont -lat -voice],  // ^sc, .s.t(h), sk(h), st(h),
		      // sp(h)
    [-cont -lat -Laryngeal] [-son +cont +Coronal] ([+nas]), // k.s(.n), k.sm,
                      // ts, ps
    [+lab +nas] [+ant +nas]   // mn
  }   ([+son -nas]),  // kj, kr, kl, kw, k.sr, k.sw, khj, gr, gl, ghr, cj, 
                      // ^jj, ^jr, ^jw, .tw, .dw, tj, tr, tw, dj, dr, dw,
                      // dhj, dhr, dhw, nj, nw, pj, pr, pl, br, bl, bhj, bhr,
                      // bhl, bhw, mj, mr, ml, ^sj, ^sr, ^sl, ^sw, .s.thj,
                      // stj, str, sphj, sj, sr, sw, hj, hr, hl, hw
  [+son],             // r, .n, n, m, l, j
  [-son] {r, w} j,    // trj, dwj
  w {l, r, j},
  [+son +cons] [-cons] }  // lw

RULES		// WB means word boundary, i.e., end of word
		// SB means syllable boundary
		// UB means utterance boundary
		// _i is an identity coindex
		// See FEATURES and SEGMENTS for further definitions.
"Depalatalization" =
  // Palatal consonants (^s, ^j) become retroflex (.s, .d) in codas
  [+cons +Coronal +Dorsal] -> [-Dorsal] / __ SB
  ;
".s-Desibilization" =
  // .s becomes .t in codas
  [-son +cont -ant] -> [-cont] / __ SB
  ;
"r-Desonorization" =
  // /r/ becomes /.z/ at end of word
  [+cons -syll +son +cont +Coronal -Dorsal] -> [-son] / __ SB WB
  ;
"Dual pragrhyatva" =
  // The dual endings /ii/, /aj/, /uu/ add a homorganic glide
  0 -> [-syll]_i / [-syll] [+syll] []_i __ SB WB<+dual-pragrhya>
  ;
"aaw-Extension" =
  // words ending in /aaw/ add another /w/
  0 -> []_i / [+low] [+low] [+lab -cons]_i __ SB WB
  ;
"ns-Extension" =
  // words ending in /n/ add /s/
  0 -> s / [+nas +Coronal] __ SB WB
  ;
"m-Dearticulation" = 
  // Words ending in /m/ dearticulate it before words beginning with an onset.
  [+lab +nas] -> [-Place] / __ SB WB SB [-syll]
  ;
"sas Apocope" =
  // A certain class of words (viz., the masc. sing. nom. pronouns /sas/
  //  and the extension /ee.sas/) drop the final /s/ before a consonant.
  [] -> 0 / __ SB WB<+s-drop> SB [-syll]
  ;
"Intralexical tsh-Splitting" =
  // /t^s/ at the beginning of an onset cluster splits off the /t/ into the
  //  preceding coda if preceded by a vowel in the same word or in a word in
  //  the no-degem class (/aa/, /maa/)
  (SB WB<+no-degem>) SB [-cont +Coronal]_t -> []_t SB / [+syll] __ [-son +high]
  ;
"awm Protection" =
  // Words ending in -a(a) drop their rhyme before the word /awm/.
  [+low] ([+low]) SB WB SB -> 0 / __ []* SB WB<+a-zap>
  ;
"WB erasure" =
  // From here on, pure postlexical (P2) rules that ignore word boundaries.
  WB -> 0
  ;
"SB simplification" =
  // Just cleans up double SB bounds left by deleted WB in SB WB SB sequence:
  SB -> 0 / SB __
  ;
"Vowel Shortening" =
  // Long vowels at the end of a syllable shorten before another word beginning
  //  with a vowel.
  [+syll]_i -> 0 / []_i __ SB [+syll]
  ;
"Like Vowel Contraction" =
  // If a syllable ends in the same vowel that the next syllable begins with
  //  (ignoring quantity), the two syllables merge, accepting all the vowels
  //  as vowels (there may be 2 or 3 of them).
  SB -> 0 / [+syll]_i __ []_i
  ;
"Diphthongization" =
  // If one syllable ends in /a/ and the next begins with a vowel
  //  (which by now cannot be /a/), that vowel, short or long,
  //  becomes nonsyllabic (i(i) -> j, u(u) -> w, .r -> r),
  //  resulting in a syllable merger.
  SB [+syll]_i ([]_i) -> [-syll]_i / [+low] __  {[-syll], SB}
  ;
"Ksaipra" =
  // If one syllable ends in a vowel (which by now must be a short vowel other
  //  than /a/) and the next begins with a vowel (which by now must be of
  //  different quality), the syllables merge by making the first vowel
  //  nonsyllabic (i -> j, u -> w, .r -> r)
  [+syll]_i SB -> [-syll]_i / __ [+syll]
  ;
"Delaryngealization" =
  // An obstruent in a coda loses its laryngealization qualities.
  [-son] -> [-Laryngeal] / __ SB
  // or just -voice
  ;
"Voice Assimilation" =
  // A non-laryngeal item in a coda takes on the voice
  //  features of the next segment, if any.
  [-Laryngeal] -> [alpha voice] / __ SB [alpha voice]
  //[-Laryngeal] -> [alpha Laryngeal] / __ SB [alpha Laryngeal]
  ;
"z-Gliding" =
  // If a syllable ends in /(a)az/, the /z/ becomes a glide.
  [+ant +cont +voice] -> [-cons +son] / [+syll -high]_a ([]_a) __    
  ;
"Rhotacization" =
  // (Elsewhere) /z/ becomes /r/.
  [+cons +cont +voice -spread] -> [+son -ant]
  ;
"e-Abhinihita" = 
  // If a syllable ends in (short) /aj/ and the next begins with /a/
  //  followed by a consonant (not a glide or /a/), the sequence /aja/
  //  is replaced by long /ee/.
  [+low] [-cons +cor -ant] SB [+low] -> e e / {SB, [-low]} __ {[+cons], SB}
  ;
"o-Abhinihita" =
  // Like e Avagraha, but works when the final glide is /w/ or the z-glide.
  [+low] [-cons {+ant, +lab}] SB [+low] -> o o / {SB, [-low]} __ {[+cons], SB}
  ;
"Udgraaha" = 
  // Glides are deleted at the end of a syllable if the next begins with a
  //  vowel.
  [-cons -syll] -> 0 / __ SB [+syll]
  ;
"e-Monophthongization" = 
  // The sequence short /a/ followed by /j/ becomes long /ee/
  [+low] [-cons +cor -ant] -> e e / {SB, [-low]} __
  ;
"o-Monophthongization" = 
  // The sequence short /a/ followed by /w/ or glide /z/ becomes
  //  long /oo/.
  [+low] [-cons {+ant, +lab}] -> o o / {SB, [-low]} __
  ;
"Long Glide Reduction" = 
  // Glides in codas (j, w) delete unless following /a/
  [-cons] -> 0 / [+syll] []* [-low] __  
  ;
"z-Glide Deletion" = 
  // Any remaining z Glide is deleted.
  [-cons +ant] -> 0
  ;
"Nasalization" = 
  // Stops become homorganic nasals at the end of a syllable before a nasal.
  [-cont -lat] -> [+nas +son] / __ SB [+nas]  
  ;
"Postlexical tsh Splitting" =
  // /t^s/ splits the /t/ into the preceding syllable iff it is monomoraic
  SB [-cont +Coronal]_t -> []_t SB / {[-syll], SB} [+syll] __ [-son +high]
  ;
"tsh Simplification" =
  // The tautosyllabic (onset) sequence /t^s/ becomes /ch/
  [-cont +Coronal] [-son +high] -> ch
  ;
"Sibilant Dearticulation" = 
  // Sibilants (/s/, /.s/) become /h/ in syllable codas.
  [-son +cont] -> [-Place +spread] / [+syll] []* __   
  ;
"Visarga Resyllabification" =
  // A fricative, /h/, at the end of a syllable moves into the following
  //  syllable if that is headed by a Coronal stop and the new onset would be 
  //  legal.
  [+cons +cont -son]_h SB -> SB []_h / __ [-cont +Coronal] [+son]
  ;
"Fricative Assimilation" = 
  // /h/ or /s/ in an onset before /c, .t, t/ assimilates to /^s, .s, s/
  [+cons +cont] -> [alpha Place -spread] / SB __ [-cont +Coronal, alpha Place]
  ;
"Nasal Dearticulation" = 
  // Nasals become /N/ before a sibilant
  [+nas] -> [-Place] / __ SB [+Coronal -son +cont]
  ;
"Nasal Assimilation" =
  // Nasals assimilate in articulation to a following oral stop
  [+nas] -> [alpha Place] / __ (SB) [-cont, -nas, alpha Place]
  ;
"n-Gemination" = 
  // Syllable-final /nC/ becomes /nn/ after a short vowel when the next
  // syllable begins with a vowel.
  [] SB -> SB []_n / {SB, [-syll]} [+syll] [+cons]_n __ [+syll]
  ;
"CC-Apocope" = 
  // Segments are deleted after consonants other than glides and /r/
  // in the coda.
  [] -> 0 / [+syll] []* [{-cont, -son}] __  
  ;
"Dental Assimilation" = 
  // /t/, /n/ at the end of a syllable assimilate in place to a coronal
  //   (palatal, dental, retroflex) oral stop /l/, or /^s/ beginning the next
  //   syllable.  The laterality of the /l/ is also assimilated
  //   (resulting in the lateral stop /dl/ or the nasal lateral /~l/).
  [+ant -cont -lat] -> 
    [alpha Place, beta lat] / 
      __ SB [+Coronal -nas {-cont, +high} alpha Place, beta lat] 
  ;
"Lateral Sonorization" =
  // The lateral stop /dl/ becomes an ordinary /l/.
  [+lat] -> [+son]
  ;
"Onset Filling" =
  // Syllable-final consonants are syllabified with a following vowel.
  [-syll]_c SB -> SB []_c / __ [+syll]
  ;
"w-Dentalization" = 
  // /w/ becomes a labiodental glide /v/ except in diphthongs
  [-syll -cons +lab] -> [-Dorsal] / {SB, [-low]} __  
  ;
"Long Diphthong Reduction" = 
  // Long vowels shorten before a tautosyllabic glide (i.e., long
  //  diphthongs become short).
  [+syll]_i ([]_i) -> 0 / __ []_i [-cons]
  ;
"Glide Vocalization" =
  // Glides in codas become vowels
  [-cons] -> [+syll] / [+low] []* __
  ;
"Coda Filling" =
  // A syllable without a coda fills it with the first element of a following
  //  branching onset.
  SB [-syll]_i -> []_i SB / [+syll] __ [-syll]
  ;
"h-Articulation" = 
  // /^h/ at the beginning of a syllable becomes a breathy voiced stop
  //  homorganic with an oral stop preceding it.
  [-Place] -> [-cont, alpha Place] / [-cont -lat -nas, alpha Place] SB __   
  ;
"sh-Desibilation" = 
  // /^s/ becomes /ch/ at the beginning of a syllable after /c/, /~n/,
  //  provided that /^s/ is not followed by an obstruent (/c/)
  [-son +cont alpha Place +high +cor -ant] -> [-cont +spread] / 
	[-cont alpha Place] SB __ [+son]
  ;
"r-Compensatory Degemination" = 
  // A syllable-final /r/ after a short vowel disappears before another /r/,
  //  resulting in compensatory lengthening.
  r -> []_i / {SB, [-syll]} [+syll]_i __ SB r  
  ;
"r-Degemination" = 
  // Other /r-r/ sequences degeminate (without lengthening).
  r -> 0 / __ SB r  
  ;
"a-Raising" = 
  // Short /a/ becomes schwa except within a diphthong.
  [+low] -> [-low] / {[-syll], SB} __ {[-syll], SB}
  ;
"SB Erasure" =
  // Erase syllable boundaries.
  SB -> 0
  ;